Към съдържанието
BGrid

XLOOKUP с примери

XLOOKUP е по-лесното търсене в таблица. Не брои колони, не се чупи, когато вмъкнете колона, търси и наляво и връща ваш текст, когато не намери нищо.

Към примерите
Таблица в BGrid, в която кодът на козунака се намира по името му с =XLOOKUP(A2,Ценоразпис!$B$2:$B$11,Ценоразпис!$A$2:$A$11,"няма")

Как се пише XLOOKUP

=XLOOKUP(търсена_стойност; масив_за_търсене; масив_за_връщане; [ако_не_е_намерено]; [режим_на_съвпадение]; [режим_на_търсене])

Задължителни са първите три аргумента. В BGrid можете да ги разделяте с точка и запетая, както в Excel на български, или със запетая.

търсена_стойност
Какво търсите: код, име, дата.
масив_за_търсене
Колоната, в която търсите. Може да е всяка колона, не само първата.
масив_за_връщане
Колоната, от която идва резултатът. Трябва да е със същата височина като масива за търсене.
ако_не_е_намерено
Текст или число, което да се покаже, когато няма съвпадение. Без него XLOOKUP връща #N/A.
режим_на_съвпадение
0 търси точно съвпадение и е по подразбиране. -1 взима точното или следващото по-малко, 1 точното или следващото по-голямо, а 2 разрешава заместващи символи * и ?.
режим_на_търсене
1 търси от първия ред надолу и е по подразбиране. -1 търси от последния ред нагоре.
Подсказката на BGrid за XLOOKUP с аргументите, пример и описание на български

Примери

Цена по код

=XLOOKUP(A2;Ценоразпис!$A$2:$A$11;Ценоразпис!$D$2:$D$11)

Същото като VLOOKUP, но без номер на колона. Вмъкнете ли колона в ценоразписа, формулата пак връща цената.

Код по име: търсене наляво

=XLOOKUP(A2;Ценоразпис!$B$2:$B$11;Ценоразпис!$A$2:$A$11;"няма")

Кодът е вляво от името. VLOOKUP не може да върне колона отляво, XLOOKUP може. За продукт, който го няма, излиза „няма“ вместо #N/A.

Последното съвпадение

=XLOOKUP(A2;Поръчки!$C$2:$C$85;Поръчки!$A$2:$A$85;"няма поръчки";0;-1)

Режим на търсене -1 търси отдолу нагоре, затова връща датата на последната поръчка на продукта, а не на първата.

XLOOKUP с режим на търсене -1, който намира датата и обекта на последната поръчка за всеки продукт

Търсене по начало на думата

=XLOOKUP("Ко*";Ценоразпис!$B$2:$B$11;Ценоразпис!$B$2:$B$11;"няма";2)

С режим на съвпадение 2 звездичката замества произволен брой знаци, а въпросителният знак замества един. „Ко*“ намира „Козунак“.

XLOOKUP със заместващ символ: търсенето „Ко*“ намира продукта „Козунак“

XLOOKUP, VLOOKUP или INDEX и MATCH

XLOOKUPVLOOKUPINDEX и MATCH
Колона за търсенеВсякаСамо първата от таблицатаВсяка
Връща колона отлявоДаНеДа
Номер на колонаНе трябваТрябва и се чупи при вмъкване на колонаНе трябва
Текст, когато няма съвпадениеВграденС IFERRORС IFERROR
Последно съвпадениеС режим -1НеНе
Къде я имаExcel 2021 и по-новите, Microsoft 365, BGridВсички версии на Excel, BGridВсички версии на Excel, BGrid

Ако пращате файла на човек с Excel 2019 или по-стар, XLOOKUP ще му покаже #NAME?. Тогава ползвайте VLOOKUP или INDEX и MATCH.

Въпроси за XLOOKUP

В кои версии на Excel има XLOOKUP?

В Excel 2021, Excel 2024, Microsoft 365 и Excel за уеб. В Excel 2019, 2016 и по-старите я няма. В BGrid я има.

Защо XLOOKUP дава #NAME?

Файлът е отворен в Excel, който няма XLOOKUP, или името на функцията е сгрешено. Ако пращате таблицата на човек със стар Excel, ползвайте VLOOKUP или INDEX и MATCH.

Защо XLOOKUP дава #VALUE!?

Масивът за търсене и масивът за връщане са с различна височина, например $B$2:$B$11 и $A$2:$A$12. Направете ги еднакви.

Различава ли XLOOKUP главни и малки букви?

Не. За нея „торта“ и „Торта“ са едно и също.

Може ли XLOOKUP да търси по две условия?

Най-просто е с помощна колона, която слепва двете стойности, например =B2&"|"&C2. После търсите по нея със същото слепване на двете условия.

Пробвайте XLOOKUP в BGrid

Безплатно, с акаунта ви в BMail. Работи и във файлове, отворени от Excel.