Към съдържанието
BGrid

VLOOKUP с примери

VLOOKUP търси стойност в първата колона на таблица и връща нещо от същия ред: цена по код, име по номер, телефон по фирма. Ето как се пише, с примери, които работят и в BGrid, и в Excel.

Как се пише
Поръчка в BGrid: цената на козунака идва от ценоразписа с формулата =VLOOKUP(A4,Ценоразпис!$A$2:$D$11,4,FALSE)

Как се пише VLOOKUP

=VLOOKUP(търсена_стойност; таблица; номер_на_колона; [точно_съвпадение])

В Excel на български аргументите се разделят с точка и запетая. BGrid приема и точка и запетая, и запетая, а показва формулата със запетаи.

търсена_стойност
Какво търсите, например кода в A2. VLOOKUP го търси само в първата колона на таблицата.
таблица
Диапазонът с данните, например Ценоразпис!$A$2:$D$11. Знаците $ го заключват, за да не се мести, когато копирате формулата надолу.
номер_на_колона
Коя колона да върне, като първата колона на таблицата е 1. В ценоразписа цената е в четвъртата колона, затова е 4.
точно_съвпадение
FALSE (или 0) търси точно съвпадение. TRUE (или пропуснато) търси приблизително и иска първата колона да е подредена от малко към голямо. Excel приема TRUE, ако го пропуснете, затова за кодове и имена винаги пишете FALSE.
Подсказката на BGrid за VLOOKUP с аргументите, пример и описание на български

Пример: цена по код от ценоразпис

Ценоразписът е в отделен лист: код, продукт, мярка и цена. В поръчката пишете само кода и броя, а продуктът и цената идват сами.

Продукт, в колона B
=VLOOKUP(A2;Ценоразпис!$A$2:$D$11;2;FALSE)
Цена, в колона D
=VLOOKUP(A2;Ценоразпис!$A$2:$D$11;4;FALSE)

Напишете формулите на първия ред и ги копирайте надолу. A2 се сменя на A3, A4 и нататък, а заключената с $ таблица остава същата.

Приблизително търсене: отстъпка според сумата

С TRUE VLOOKUP не търси точно съвпадение, а най-голямата стойност, която не е над търсената. Така работи всяка скала: отстъпки, комисиони, оценки, прагове.

=VLOOKUP(E8;Отстъпки!$A$2:$B$5;2;TRUE)

Скалата е от 0 € без отстъпка, от 50 € 3 %, от 100 € 5 % и от 250 € 8 %. За поръчка от 332,50 € формулата връща 8 %, защото сумата е над 250 €.

Първата колона на скалата трябва да е подредена от малко към голямо, иначе резултатът е грешен.

Поръчка в BGrid с обща сума 332,50 € и отстъпка 8 %, намерена с VLOOKUP в скалата с отстъпки

Защо VLOOKUP дава #N/A

  • Стойността я няма в първата колона: код П-120 не е в ценоразписа.
  • Интервал в края или в началото: „П-103 “ и „П-103“ за таблицата са различни.
  • Число, записано като текст: 101 и „101“ не съвпадат.
  • Таблицата не започва с колоната, в която търсите. VLOOKUP гледа само първата колона на диапазона.
  • Формулата е копирана без $ и таблицата се е изместила надолу заедно с нея.
Ваш текст вместо #N/A
=IFERROR(VLOOKUP(A3;Ценоразпис!$A$2:$D$11;2;FALSE);"Няма такъв код")
Без интервалите преди търсенето
=IFERROR(VLOOKUP(TRIM(A3);Ценоразпис!$A$2:$D$11;2;FALSE);"Няма такъв код")
Три кода в BGrid: с интервал в края и с несъществуващ код VLOOKUP връща #N/A, а с IFERROR излиза „Няма такъв код“Формула с IFERROR и TRIM, която намира кода и с интервал в края

#REF! значи, че номерът на колоната е по-голям от броя на колоните в таблицата.

VLOOKUP или XLOOKUP

XLOOKUP е по-новата функция за същото. Търси във всяка колона, връща стойности и отляво, не брои колони и има свой текст, когато не намери нищо. Има я в Excel 2021, Excel 2024, Microsoft 365 и в BGrid, но я няма в Excel 2019 и по-старите. За тях класическата замяна е INDEX и MATCH:

=INDEX(Ценоразпис!$D$2:$D$11;MATCH(A2;Ценоразпис!$A$2:$A$11;0))

Примери с XLOOKUP: търсене наляво, последно съвпадение и свой текст при липса.

Въпроси за VLOOKUP

Какво означава VLOOKUP?

Vertical lookup, вертикално търсене: функцията търси надолу по първата колона на таблицата. В Excel на руски се казва ВПР. Сестрата ѝ HLOOKUP търси по първия ред.

Защо VLOOKUP дава #N/A, а стойността я има?

Най-често заради интервал в края, число, записано като текст, или таблица, която не започва с колоната за търсене. Пробвайте с TRIM и проверете дали диапазонът е заключен с $.

Различава ли VLOOKUP главни и малки букви?

Не. За нея „козунак“ и „Козунак“ са едно и също.

Какво връща VLOOKUP, ако има няколко съвпадения?

Първото отгоре надолу. За последното съвпадение ползвайте XLOOKUP с режим на търсене -1.

Може ли VLOOKUP да търси в друг лист?

Да, в друг лист на същия файл, например Ценоразпис!$A$2:$D$11. В BGrid няма връзки към други файлове, затова копирайте таблицата за търсене в отделен лист.

Как да търся по две условия?

Добавете в началото на таблицата помощна колона, която слепва двете стойности, например =B2&"|"&C2, и търсете по нея със същото слепване: =VLOOKUP(G2&"|"&H2;A2:E100;5;FALSE).

Пробвайте VLOOKUP в BGrid

Безплатно, с акаунта ви в BMail. Отворете своя файл от Excel или започнете празна таблица.